SPARQL et Wikidata. Partie 2 : images, cartes, frises chronologiques, graphiques

On trouve de tout dans Wikidata, en quantité et bien souvent en qualité également. De plus, ces données structurées peuvent être interrogées à l’aide du langage de requête SPARQL. Les tableaux de données obtenus en retour peuvent être explorés et visualisés de différentes manières à l’aide de l’interface nommée Wikidata Query Service (WDQS). Dans ce deuxième tutoriel, une requête SPARQL simple est d’abord posée : les mathématiciennes françaises référencées dans Wikidata. Puis la recherche est rendue progressivement plus complexe et de nouvelles informations sont affichées. Les réponses sont vues d’abord sous forme d’un tableau dont le nombre de ligne indique le nombre de personnes trouvées dans Wikidata. Les résultats sont ensuite affichés sous forme de carte du lieu de naissance, de galerie d’images, de frise chronologique. Une frise particulièrement ergonomique peut être créée à l’aide du service externe HistropediaJS. SPARQL permet de poser des questions relativement complexes et montre également certaines limites. Les effectifs des mathématiciens par année de naissance sont visualisés sous forme de graphique.

  1. Requêtes SPARQL avec Wikidata
  2. Les mathématiciennes françaises référencées dans Wikidata
    • 2.1 Première requête
    • 2.2 Carte des lieux de naissance
    • 2.3 Panneau d’images
    • 2.4 Une frise chronologique
    • 2.5 Une frise avec Histropedia JS
    • 2.6 Champs répétés : les nationalités
  3. Mathématiciennes et mathématiciens
    • 3.1 Une liste des mathématiciennes au niveau mondial
    • 3.2 Les mathématiciennes, politiques nationales de recherche
    • 3.3 Géographie historique des mathématiciennes
    • 3.4 Tous les mathématiciens
    • 3.5 Graphique des effectifs par année de naissance
    • 3.6 Effectif par décade, lissage

Voir aussi : Partie 1

1. Requêtes SPARQL avec Wikidata

De manière générale, les requêtes SPARQL du type SELECT sont composées de deux parties obligatoires (SELECT et WHERE) et de trois parties facultatives (PREFIX, FROM et les modificateurs). La clause SELECT définit les colonnes du tableau de données attendu en retour. L’instruction WHERE spécifie essentiellement les critères de recherche. Les modificateurs localisés après WHERE rendent possible les regroupements et les tris. Wikidata contient de plus un certain nombre de spécificités. Dans ce tutoriel, de fréquents liens sont donnés vers le livre électronique de HenkvD localisé sous WikiBooks. Des précisions et des exemples supplémentaires y sont disponibles en anglais.

Les parties optionnelles (à gauche) et obligatoires d’une requête SPARQL, d’après KBpedia : Lien
  • SPARQL, Basics, Wikibooks, HenkvD : Lien
  • SPARQL, Modifiers, Wikibooks, HenkvD : Lien
  • SPARQL, Prefixes, Wikibooks, HenkvD : Lien

2. Les mathématiciennes françaises référencées dans Wikidata

Une requête SPARQL classique est tout d’abord posée : les mathématiciennes françaises référencées dans Wikidata. On peut pour commencer visualiser la notice d’une mathématicienne bien connue comme par exemple Émilie du Châtelet Q7286 afin d’en observer les propriétés renseignées. Celles qui nous intéressent peuvent être notées pour élaborer une requête. L’interface (Explorer) permet de visualiser plusieurs éléments sous forme de graphe de connaissance. Nous pouvons bien sûr en savoir plus sur cette mathématicienne française en consultant un article comme celui de Mireille Touzery.

  • Mireille Touzery, « Émilie Du Châtelet, un passeur scientifique au XVIIIe siècle », La revue pour l’histoire du CNRS [Online], 21 | 2008, Online since 03 July 2010, connection on 05 May 2022. URL : http://journals.openedition.org/histoire-cnrs/7752 ; DOI : https://doi.org/10.4000/histoire-cnrs.7752
Une partie des graphes d’Émilie du Châtelet et de son fils Louis Marie Florent

2.1 Première requête

L’activité professionnelle de mathématicien est renseignée à l’aide de la propriété P106 à laquelle la valeur Q170790 est donnée. Le motif de triplet (“?personne”, “wdt:P106 occupation”, “wd:Q170790 mathématicien”) est cherché dans lequel “wdt” est le préfixe des propriétés et “wd” celui des valeurs. Un deuxième motif (“?personne”, “wdt:P21 sexe ou genre”, “wd:Q6581072 féminin”) permet de trouver les mathématiciennes. La nationalité française est cherchée avec (“?personne”, “wdt:P27 pays de citoyenneté”, “wd:Q142”). Le service “SERVICE wikibase:label” appelé dans WHERE permet de disposer d’un raccourci pour accéder aux libellés, descriptions et libellés alternatifs. Les suffixes “Label”, “Description” ou “AltLabel” sont ajoutés au nom de la variable. Ainsi, l’accès au libellé de la variable “?personne” est donné par “?personneLabel”; l’accès à une brève description est donné par “?personneDescription”. La partie SELECT spécifie les colonnes du tableau de résultat à afficher. 121 résultats sont trouvés à l’aide de la Requête 1 :

# Les mathématiciennes françaises
SELECT ?personne ?personneLabel
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}

On obtient le tableau dans lequel un tri par identifiant Wikidata peut être obtenu en cliquant sur le libellé de colonne du tableau.

personnepersonneLabel
wd:Q7103Sophie Germain
wd:Q7286Émilie du Châtelet
wd:Q16445Michèle Vergne
wd:Q266049Nicole-Reine Lepaute
4 premières valeurs d’un tableau de 121 lignes
  • SPARQL, Wikidata Query Service – Introduction, HenkvD : Lien
  • SPARQL, SERVICE – Label, Wikibooks, HenkvD : Lien
  • SPARQL, Triples, Wikibooks, HenkvD : Lien

2.2 Carte des lieux de naissance

On s’intéresse ensuite au lieu de naissance. Celui-ci peut être renseigné ou absent d’où l’emploi d’OPTIONAL appliquée au motif (“?personne”, “wdt:P19 lieu de naissance”, “?lieuNaissance”). La variable “?lieuNaissanceLabel” est ajoutée dans SELECT :

# Les mathématiciennes françaises, lieu de naissance
SELECT ?personne ?personneLabel ?lieuNaissanceLabel
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {?personne wdt:P19 ?lieuNaissance.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
personnepersonneLabellieuNaissanceLabel
wd:Q7103Sophie GermainParis
wd:Q7286Émilie du ChâteletParis
wd:Q16445Michèle VergneL’Isle-Adam
Les 3 premiers résultats

Ce lieu peut être géolocalisé. Si l’on cherche par exemple la ville de L’Isle-Adam Q911450 dans le moteur classique de Wikidata (situé en haut à droite de l’interface), on remarque que les coordonnées sont données par P625. Le motif de triplet à ajouter est donc (“?lieuNaissance”, “wdt:P625“, “?localisation”). Le résultat peut alors être affiché indifféremment sous forme de tableau ou de carte géographique en choisissant “Map” dans l’onglet des visualisations : Requête 2

# Les mathématiciennes françaises, lieu de naissance, localisation
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
personnepersonneLabellieuNaissanceLabellocalisation
wd:Q104173Hélène EsnaultParisPoint(2.351388888 48.856944444)
wd:Q266049Nicole-Reine LepauteParisPoint(2.351388888 48.856944444)
wd:Q274751Élisabeth LutzThannPoint(7.104444444 47.806666666)
Lieux de naissance des mathématiciennes françaises

2.3 Panneau d’images

Il est maintenant possible de chercher des images (gravures, peintures, photos) associées à ces mathématiciennes. Si l’on affiche Émilie du Châtelet de nouveau, un portrait est associé en valeur de la propriété P18. Le motif de triplet (“?personne”, “wdt:P18 image”, “?image”) donne l’URL de l’image dans Wikimedia Commons, la médiathèque de Wikipédia. Le tableau est ensuite affiché sous forme de panneau d’images à l’aide de l’outil “Image grid”.

# Les mathématiciennes françaises, lieu de naissance, image
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation ?image
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P18 ?image.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
Images des mathématiciennes françaises

2.4 Une frise chronologique sous Wikidata

La notice d’Émilie du Châtelet Q7286 fournit encore les propriétés “P569 date de naissance” et “P570 date de mort”. Ces motifs sont déclarés optionnels car les dates ne sont pas toujours renseignées. Les valeurs du tableau sont ordonnés par date de naissance à l’aide du modificateur ORDER BY placé en fin de requête :

# Les mathématiciennes françaises, lieu de naissance, image, dates
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation ?image ?dateNaissance ?dateDeces
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P18 ?image.}
  OPTIONAL {?personne wdt:P569 ?dateNaissance.}
  OPTIONAL {?personne wdt:P570 ?dateDeces.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
ORDER BY ?dateNaissance

On observe de manière étonnante l’obtention de 127 résultats en lieu et place des 121 obtenus précédemment. Les doublons correspondent aux notices pour lesquelles plusieurs dates de naissance ou de décès sont renseignées. Ainsi, la date de décès de Marie-Jeanne de Lalande est référencée au 8 novembre 1832 par Wikipédia, et à l’année 1832 par le MacTutor History of Mathematics Archive. Il serait intéressant pour notre tableau de disposer d’une date unique.

L’instruction SAMPLE dans SELECT permet de n’afficher qu’une seule valeur si les images, les dates de naissance et de décès sont plusieurs fois présentes. Le modificateur utilisé conjointement GROUP BY permet de regrouper les notices présentant plusieurs valeurs en une seule. Les variables mentionnées dans GROUP BY sont ici toutes les variables présentes dans SELECT hormis celles échantillonnées à l’aide de SAMPLE. La requête devient ainsi Requête 3 :

# Les mathématiciennes françaises, lieu de naissance, image, dates
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
  (SAMPLE(?images) AS ?image)  
  (SAMPLE(?datesNaissance) AS ?dateNaissance)
  (SAMPLE(?datesDeces) AS ?dateDeces)
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P18 ?images.}
  OPTIONAL {?personne wdt:P569 ?datesNaissance.}
  OPTIONAL {?personne wdt:P570 ?datesDeces.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}
GROUP BY ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
ORDER BY ?dateNaissance

Les 121 mathématiciennes françaises sont de nouveau retrouvées. Les mêmes notices peuvent être visionnées sous forme de tableau, de mur d’image, de carte géographique ou de frise chronologique.

personnepersonneLabellieuNaissanceLabellocalisationimagedateNaissancedateDeces
wd:Q7103Sophie GermainParisPoint(2.351388888 48.856944444) commons:Germain.jpeg1 avril 177627 juin 1831
wd:Q7286Émilie du ChâteletParisPoint(2.351388888 48.856944444) commons:Okänd – Gabrielle-Émilie Le Tonnelier de Breteuil (1706–1749), Marquise du Châtelet – NMDrh 796 – Nationalmuseum.jpg17 décembre 170610 septembre 1749
wd:Q16445Michèle VergneL’Isle-AdamPoint(2.222777777 49.111111111) commons:Michele Vergne.jpg29 août 1943
Frise chronologique Wikidata des mathématiciennes françaises

2.5 Une frise chronologique avec Histropedia JS

Cependant, la visualisation de la chronologie se montre peu ergonomique sous Wikidata et un nouveau service est testé. Hispropedia JS est à la fois une bibliothèque Javascript et un service en ligne de création de frise chronologique. Une des fonctionnalités du site est de permettre l’entrée de requêtes SPARQL Wikidata et d’afficher en retour une frise chronologique plus ergonomique. Il est possible de zoomer avec la molette de la souris sur une zone plus densément renseignée. De nouvelles notices apparaissent. Un double clic donne l’accès à la notice Wikidata. La frise peut être partagée et des exports en divers formats sont possibles. On remarque au passage sur la ligne de base l’important nombre des mathématiciennes référencées à partir de 1940, expliquant les difficultés en terme d’ergonomie de l’outil sous Wikidata.

Une chronologie des mathématiciennes françaises avec Histropedia JS : Lien
  • Histropedia – Wikidata Query Timeline (beta) : Lien

2.6 Champs répétés : les nationalités

La question de la nationalité nécessite de prendre en compte les binationaux et le cas des pays dont le nom a changé. La nationalité peut ne pas être renseignée, avoir une valeur ou bien admettre plusieurs valeurs. Un exemple d’une mathématicienne binationale pourrait être Liouba Bortniker Q51954788. Celle-ci naît le 20 mai 1860 à Alexandrowka en Ukraine alors partie intégrante de la Russie. Nous souhaitons concaténer dans une seule colonne le libellé en français des nationalités éventuellement multiples. Toutes les nationalités sont cherchées avec le motif optionnel (“?personne”, “wdt:P27”, “?nationalites”). Dans la partie SELECT, une seule nationalité est affichée sous forme d’identifiant avec SAMPLE. Les libellés sont concaténés à l’aide de la clause GROUP_CONCAT. L’usage de cette clause entraine avec Wikibase un effet de bord qui fait que les valeurs de ?personneLabel ?lieuNaissanceLabel et ?nationalitesLabel sont perdues. Celles-ci peuvent être retrouvées de manière aisée en ajoutant dans la partie “SERVICE wikibase:label” les libellés dont l’affichage est souhaité. Requête 4 :

# Les mathématiciennes françaises, leurs nationalités
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
  (SAMPLE(?images) AS ?image)  
  (SAMPLE(?datesNaissance) AS ?dateNaissance)
  (SAMPLE(?datesDeces) AS ?dateDeces)
  (SAMPLE(?nationalites) AS ?nationalite)
  (GROUP_CONCAT(DISTINCT ?nationalitesLabel; separator=", ") AS ?listeNat)
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  ?personne wdt:P27 wd:Q142.     #France
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P18 ?images.}
  OPTIONAL {?personne wdt:P569 ?datesNaissance.}
  OPTIONAL {?personne wdt:P570 ?datesDeces.}
  OPTIONAL {?personne wdt:P27 ?nationalites.}
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
    ?personne rdfs:label ?personneLabel.
    ?lieuNaissance rdfs:label ?lieuNaissanceLabel.
    ?nationalites rdfs:label ?nationalitesLabel.
  }
}
GROUP BY ?personne ?personneLabel ?lieuNaissanceLabel ?localisation ?listeNat
ORDER BY ?dateNaissance

La requête fournit les 121 réponses habituelles. On dénombre 10 femmes mathématiciennes françaises multinationales sur 121. Les multiples nationalités correspondent dans Wikidata soit au cas de personnes immigrées ou émigrées, soit à un changement de nom du pays d’origine (ex: Empire Russe, URSS).

wd:Q51954788Liouba BortnikerAlexandrovkaPoint(41.355277777 52.280833333)20 mai 18601 janvier 1900 wd:Q142France, Empire russe
wd:Q42887333Anna Cartan15 mai 18781 janvier 1923 wd:Q142France
wd:Q51955179Jeanne RouvièreBesançonPoint(6.021388888 47.242222222)21 janvier 18921 janvier 1970 wd:Q142France
wd:Q51955135Georgette FlamantChalon-sur-SaônePoint(4.853888888 46.781111111)3 janvier 18955 juillet 1958 wd:Q142France

La même méthode peut être employée avec d’autres champs multivalués comme P101 (domaine d’activité : mathématicien), P106 (activité professionnelle : mathématicien, physicien), P463 (membre de), langues parlées, études suivies, est influencé par, etc. Les clauses GROUP_CONCAT, SAMPLE, et d’autres sont documentées sous le nom de fonctions d’agrégation.

  • SPARQL, Aggregate functions – Label, Wikibooks, HenkvD : Lien

3. Mathématiciennes et mathématiciens

La question est élargie à l’ensemble des mathématiciennes, puis à tous les mathématiciens référencés dans Wikidata. Les temps de réponse avec des questions complexes est important et de l’ordre de quelques secondes à plusieurs dizaines de secondes.

3.1 Une liste des mathématiciennes au niveau mondial

La requête 4 est reprise en commentant à l’aide de # le motif du pays de citoyenneté. 3377 résultats sont obtenus en 10 secondes. Du fait du nombre de résultat supérieur à 200, le tableau de résultats est affiché dans l’interface sous forme paginée. Le nombre standard de 200 lignes peut être personnalisé en bas de page à gauche. Un moteur de recherche (Search) sensible à l’accentuation localisé en haut à droite rend possible l’exploration de l’ensemble. On peut ainsi rechercher dans ce groupe les mathématiciennes italiennes par exemple. La carte des lieux de naissance peut être affichée. Requête 5.

Les mathématiciennes triées par identifiant Wikidata
Carte des lieux de naissance des mathématiciennes de Wikidata

3.2 Les mathématiciennes, politiques nationales de recherche

Des variables d’un nom particulier comme par exemple “?layer” jouent des rôles spéciaux dans l’interface de cartographie de Wikidata. Les contenus de “?layer” sont visualisés sous forme d’une couche de donnée de couleur particulière possible à sélectionner individuellement. On obtient 3377 mathématiciennes dont certaines ont un lieu de naissance géolocalisé ainsi qu’une nationalité renseignée. Requête 6.

# Les mathématiciennes, naissance et nationalité
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
  (SAMPLE(?nationalitesLabel) AS ?layer)
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P27 ?nationalites.}
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
    ?personne rdfs:label ?personneLabel.
    ?lieuNaissance rdfs:label ?lieuNaissanceLabel.
    ?nationalites rdfs:label ?nationalitesLabel.
  }
}
GROUP BY ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
personnepersonneLabellieuNaissanceLabellocalisationlayer
wd:Q520382Elizabeth ScottFort SillPoint(-98.508333333 34.704166666)États-Unis
wd:Q522359Valentina BorokKharkivPoint(36.231111111 49.9925)Ukraine
wd:Q526401Cécile DeWitt-Morette6e arrondissement de ParisPoint(2.332233333 48.850530555)France
wd:Q528763Maria ChudnovskyUnion des républiques socialistes soviétiquesPoint(90.0 65.0)Israël
Lieu de naissance des mathématiciennes, colorié par nationalité

Il devient ensuite possible à l’aide de cet échantillon d’observer les politiques nationales récentes en matière de recherche scientifique et de naturalisation pour le domaine des mathématiques. Il suffit dans la partie des couches de la carte de sélectionner le pays dont on souhaite observer la politique. De nombreux pays comme les États-Unis, le Canada, la Suisse, le Royaume-Uni, la France semblent mener une politique d’accueil plus ou moins large et attirer les talents, alors que d’autres comme l’Allemagne ou l’Italie semblent former et employer plutôt localement.

Lieux de naissance des mathématiciennes de nationalité américaine
Lieux de naissance des mathématiciennes allemandes, italiennes et britanniques

3.3 Géographie historique des mathématiciennes

Les lieux de naissance des mathématiciennes peuvent être visualisés simultanément sur une carte avec leur date de naissance sur laquelle un calcul d’appartenance à une période historique est réalisé. Les périodes suivantes sont distinguées : avant 1700, de 1700 à 1750, de 1751 à 1800 et ainsi de suite jusqu’à après 1940. On obtient un tableau de 3406 mathématiciennes en 10 secondes. La localisation du lieu de naissance ainsi que la date sont simultanément connues pour 1447 de celles-ci. Requête 7

# Les mathématiciennes, par année de naissance
#defaultView:Map
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
  (SAMPLE(?datesNaissance) AS ?dateNaissance)
  (SAMPLE(?datesDeces) AS ?dateDeces)
  (SAMPLE(?anneesNaissance) AS ?anneeNaissance)
  (SAMPLE(?nationalitesLabel) AS ?nationaliteLabel)
  (SAMPLE(?layers) AS ?layer)
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P21 wd:Q6581072. #féminin
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P569 ?datesNaissance.}
  OPTIONAL {?personne wdt:P570 ?datesDeces.}
  OPTIONAL {?personne wdt:P27 ?nationalites.}
  BIND(YEAR(?datesNaissance) as ?anneesNaissance)
  BIND(
    IF((?anneesNaissance < 1700), "Pre-1700", 
       IF((?anneesNaissance < 1751), "1700-1750", 
          IF((?anneesNaissance < 1801), "1751-1800", 
             IF((?anneesNaissance < 1851), "1801-1850", 
                IF((?anneesNaissance < 1901), "1851-1900", 
                   IF((?anneesNaissance < 1940), "1901-1940", 
                      "Post-1940"
     ) ) ) ) )) AS ?layers )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
    ?personne rdfs:label ?personneLabel.
    ?lieuNaissance rdfs:label ?lieuNaissanceLabel.
    ?nationalites rdfs:label ?nationalitesLabel.
  }
}
GROUP BY ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
ORDER BY ?dateNaissance
personnepersonneLabellieuNaissanceLabellocalisationdateNaissancedateDecesanneeNaissancenationaliteLabellayer
wd:Q111805289Beulah Russell1 janvier 18781 janvier 194018781851-1900
wd:Q111782501Rosa FerrentinoItalie
wd:Q111755654Chiara NicoteraNaplesPoint(14.25 40.833333333)26 août 19671967Post-1940
wd:Q111745840Tiziana DuranteItalie
wd:Q111745454Patricia Díaz de AlbaCadixPoint(-6.2975 36.535)20 mai 19881988EspagnePost-1940
Tableau des résultats
Carte des lieux de naissance des mathmématiciennes en fonction de l’époque

3.4 Tous les mathématiciens

Le motif de sélection du genre est supprimé. Plus de 10000 résultats sont attendus et une requête simplifiée doit être posée afin d’être acceptée en terme de temps de calcul. On obtient ainsi 30391 résultats en 59 secondes lorsque les serveurs ne sont pas surchargés. Une carte des lieux de naissance avec visualisation des marqueurs sous forme d’amas est demandée en spécifiant l’option “markercluster”. Avec cette option, la carte est visionnée par défaut en résultat de requête en lieu et place du tableau. Il est aussi possible de naviguer d’interroger et d’exporter le tableau des résultats en JSON, CSV, TSV, HTML. Le temps de calcul est important et l’obtention d’une réponse dépend de la charge des machines au moment ou elle est posée. Elle n’aboutit généralement pas et d’autres méthodes devraient être employées.

# Les mathématiciens
#defaultView:Map{"markercluster":{} }
SELECT ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
  (SAMPLE(?datesNaissance) AS ?dateNaissance)
  (SAMPLE(?datesDeces) AS ?dateDeces)
  (SAMPLE(?nationalitesLabel) AS ?nationaliteLabel)
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  OPTIONAL {
    ?personne wdt:P19 ?lieuNaissance.
    ?lieuNaissance wdt:P625 ?localisation.
  }
  OPTIONAL {?personne wdt:P569 ?datesNaissance.}
  OPTIONAL {?personne wdt:P570 ?datesDeces.}
  OPTIONAL {?personne wdt:P27 ?nationalites.}
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
    ?personne rdfs:label ?personneLabel.
    ?lieuNaissance rdfs:label ?lieuNaissanceLabel.
    ?nationalites rdfs:label ?nationalitesLabel.
  }
}
GROUP BY ?personne ?personneLabel ?lieuNaissanceLabel ?localisation
ORDER BY ?dateNaissance
Carte des lieux de naissance des mathématiciens, avec amas de marqueurs

3.5 Graphique des effectifs par année de naissance

Comme SQL ou EXCEL, SPARQL propose des fonctions de calcul susceptibles de servir à l’établissement de tableaux statistiques. La fonction COUNT est souvent utilisée pour parcourir les données regroupées. On obtient à l’aide de la requête suivante un tableau à deux colonnes de 752 lignes correspondant à 752 années au cours desquelles au moins un mathématicien de Wikidata est né. Un filtre des années de naissance positives est rendu nécessaire pour l’affichage à l’aide de l’option “LineChart”. On remarque en terme d’effectif par décade la croissance exponentielle du nombre de mathématicies référencés dans Wikidata à partir de 1800 environ. La chute des effectifs après la décade 1950 est remarquée, de même que le pic de l’année 2000. Requête 8

#Effectif des mathématiciens par année de naissance
#defaultView:LineChart
SELECT ?anneeNaissance (COUNT(?anneeNaissance) AS ?effectif) 
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P569 ?datesNaissance.
  BIND(YEAR(?datesNaissance) as ?anneeNaissance). 
  FILTER( ?anneeNaissance > 0)
}
GROUP BY ?anneeNaissance
ORDER BY ?anneeNaissance
anneeNaissanceeffectif
1904100
1905133
1906144
1907140

3.6 Effectif par décade, lissage

Une manière simple de lisser les données est de calculer la décade de la date de naissance. Celle-ci est obtenue en divisant par 10 l’année de naissance, puis en arrondissant à l’aide de la fonction ROUND, et en multipliant le tout par 10. Requête 9

#Effectif des mathématiciens par décade de l'année de naissance
#defaultView:LineChart
SELECT ?decade (COUNT(?decade) AS ?effectif) 
WHERE {
  ?personne wdt:P106 wd:Q170790. #mathématicien
  ?personne wdt:P569 ?datesNaissance.
  BIND(YEAR(?datesNaissance) as ?anneeNaissance). 
  BIND(ROUND(?anneeNaissance/10)*10 as ?decade).
  FILTER( ?anneeNaissance > 0)
}
GROUP BY ?decade
ORDER BY ?decade

3.6 Une histoire du genre en mathématiques ?

# Une histoire du genre en mathématiques 
#defaultView:LineChart
SELECT 
(SAMPLE(?annee) AS ?annee) 
(SAMPLE(?classeLabel) AS ?classeLabel) 
(COUNT(?classe) AS ?count) 
WHERE {
  ?personne wdt:P106 wd:Q170790. # Mathématicien
  ?personne wdt:P569 ?dateNaissance.
  ?personne wdt:P21 ?classe.
  BIND(STR(YEAR(?dateNaissance)) AS ?annee)
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?classe rdfs:label ?classeLabel. }
}
GROUP BY ?annee ?classe
ORDER BY ?classe

Conclusion

La question du genre dans le domaine de l’histoire des mathématiques est abordée dans divers articles académiques. Les mathématiciennes référencées se montrent relativement nombreuses et Wikidata interrogé à l’aide de SPARQL permet d’apporter de multiples visualisations interactives à moindre frais. Des renseignements quantitatifs de première approche sont ainsi trouvés, susceptibles d’apporter des renseignements statistiques ou bien biographiques.

Huit requêtes SPARQL relativement simples sont proposées. Elles peuvent être aisément adaptées à d’autres problématiques en changeant un faible nombre de motifs de triplets. Wikidata se montre susceptible d’apporter des renseignements multiples dont le nombre et la consistance vont augmenter dans les années qui viennent. Très bonne exploration de Wikidata et usage de SPARQL ! [A suivre…]

  • SPARQL/Views – Label, Wikibooks, HenkvD : Lien
  • Stewart, Abigail J. “Mathematics, Gender, and Generation: The Development of Women Mathematicians in the Postwar Period.” Human Development, vol. 45, no. 6, 2002, pp. 441–45, https://www.jstor.org/stable/26763711
  • Jenny Boucard, Isabelle Lémonon. “ Women in Mathematics: Historical and Modern Perspectives ” Réflexions sur les femmes en mathématiques. 2018. hal-02049374
1 Star2 Stars3 Stars4 Stars5 Stars (Pas encore noté)
Loading...

Laisser un commentaire